Umumiy anodli 7 segmentli, 4 xonali belgini qanday ishlatish kerak?

Pavlusning javobiga qo'shimcha sifatida men ko'rsatadigan qisqa dasturni yozdim uning 7-segmentli 4-raqamli ekranini qanday suratga olish kerak:

Bu aslida umumiy katodli displey hisoblanadi, shuning uchun dastur, shuningdek raqamning alohida kabellari. Qiziqarli qism vaqti-vaqti bilan chaqirilishi kerak bo'lgan refresh_display() funktsiyasi. Algoritm quyidagicha:

• raqamlardan biri uchun tegishli signallari bilan 7 anodni boshqaring
ni ko'rsatishni xohlaymiz
• HIGH raqamini katodini boshqaruvchi chiqdi NPN tranzistorlari.
• 2.5 msni kuting (100 Hz yangilash tezligi uchun)
• LOW ni katot-nazorat qiluvchi chiqdi
ni o'rnating
• keyingi raqamga o'ting.

Shuni ta'kidlash kerakki, kutish CPUni blokirovka qilmasdan amalga oshiriladi "Blink Without Kechikish tutorial. Mana dastur:

const int NB_DIGITS     = 4; //4-digit display
const int FIRST_ANODE   = 2; //anodes a..g on pins 2..8
const int FIRST_CATHODE = 9; //cathodes, right to left, on pins 9..12

// Digits to display, from right to left.
uint8_t digits[NB_DIGITS];

// Set all the used pins as outputs.
void init_display()
{
    for (int i = 0; i < 7; i++)
        pinMode(FIRST_ANODE + i, OUTPUT);
    for (int i = 0; i < NB_DIGITS; i++)
        pinMode(FIRST_CATHODE + i, OUTPUT);
}

// This should be called periodically.
void refresh_display()
{
   //Our 7-segment "font".
    static const uint8_t font[10] = {
        //abcdefg
        0b1111110,//0
        0b0110000,//1
        0b1101101,//2
        0b1111001,//3
        0b0110011,//4
        0b1011011,//5
        0b1011111,//6
        0b1110000,//7
        0b1111111,//8
        0b1111011 //9
    };

   //Wait for 2.5 ms before switching digits.
    static uint32_t last_switch;
    uint32_t now = micros();
    if (now - last_switch < 2500) return;
    last_switch = now;

   //Switch off the current digit.
    static uint8_t pos;
    digitalWrite(FIRST_CATHODE + pos, LOW);

   //Set the anodes for the next digit.
    pos = (pos + 1) % NB_DIGITS;
    uint8_t glyph = font[digits[pos]];
    for (int i = 0; i < 7; i++)
        digitalWrite(FIRST_ANODE + i, glyph & 1 << (6-i));

   //Switch digit on.
    digitalWrite(FIRST_CATHODE + pos, HIGH);
}

/***********************************************************************
 * Example usage.
 */

void setup()
{
    init_display();
}

void loop()
{
    uint32_t now = millis();

   //Change the number displayed every second.
    static uint32_t last_change;
    if (now - last_change >= 1000) {
        digits[3] = digits[2];
        digits[2] = digits[1];
        digits[1] = digits[0];
        digits[0] = (digits[0] + 1) % 10;
        last_change = now;
    }

    refresh_display();
}

Pavel o'quv qo'llanmasiga link berdi. Parallax Bu esa Multiplex7Seg Arduino kutubxonasi. Ushbu kutubxona misol kodidan ko'ra umumiydir yuqorida aytilganidek, ishlatilgan pinlar haqida taxminlar keltirmaydi. Lekin katta kutubxona bilan bu kodning orasidagi farq vaqtni belgilaydi boshqariladi:

• Kutubxonani Taymer 2 to'ldirishni to'xtatish orqali boshqariladi. Bu kerak bir taymerga ega bo'lish uchun juda barqaror vaqtni ta'minlash Ushbu ishga bag'ishlangan.
• Yuqoridagi kod tez-tez refresh_display() deb nomlangan foydalanuvchini qo'llab-quvvatlaydi yetarli. Bu alohida qo'shimcha qurilmalarga kerak emas, lekin u loop() uchun juda uzoq vaqt talab qilinadigan dasturlar bilan yaxshi o'ynashmaydi: u delay() deb chaqirganingiz kabi bo'lmaydi.